Finding the flow on center manifolds using Taylor series

In this notebook, we will find the first few terms in the Taylor series of a center manifold and use it to understand the flow on that manifold and analyze the stability of a restpoint.

A nonhyperbolic restpoint in R^2

Here is a simple ODE in the plane with an equilibrium at the origin and a zero eigenvalue. The center subspace is the x axis

xdot = -x*y + y^3
ydot = -y + x^2

The center manifold will be a graph y = psi(x).  Here are the first few terms of a Taylor series for such a function, assuming the graph is tangent to the x axis.

psi =  a2*x^2+a3*x^3+a4*x^4

If the graph is invariant we will have ydot = psi’(x) xdot when y =  psi(x).

invarianceeq = ydot - D[psi,x]*xdot/.y->psi//Expand

We need to set the coefficients of this quantity equal to zero to find the unknown coefficients of psi.

Coefficient[invarianceeq,{x^2,x^3,x^4}]
asol =Solve[%=={0,0,0},{a2,a3,a4}][[1]]
psi0= psi/.asol
Plot[psi0,{x,-1,1}]

To find the ODE on this invariant curve we can use x as a coordinate and just substitute psi for y.  Since the series for y was correct through order 4,  this ODE will be correct through order 5.

xdotcenter = xdot/.y->psi0//Expand

In fact the first term  xdot = -x^3 + ...  shows that x=0 is asymptotically stable in the center space.  Since the other eigenvalue is attracting, the theory guarantees that (0,0) is asymptotically stable in R^2.

A center in 3D

The following ODE has an equilbrium point at the origin in R^3. The center subspace is the (x,y) plane.

xdot= -y+x*z;
ydot = x;
zdot = -z+x*y;

The center manifold will be a graph z = psi(x,y).  Here are the first few terms of a Taylor series for such a function, assuming the graph is tangent to the (x,y) plane.

psi = Sum[a[i,2-i]*x^i*y^(2-i),{i,0,2}]+
Sum[a[i,3-i]*x^i*y^(3-i),{i,0,3}]

If the graph is invariant we should have zdot = D[psi,x]*xdot + D[psi,y]*ydot when z= psi(x,y).

invarianceeq = zdot - D[psi,x]*xdot-D[psi,y]*ydot /.z->psi

We need to set the coefficients of this quantity equal to zero to find the unknown coefficients of psi. Start with coefficients of degree 2.

cl2 =  Table[Coefficient[invarianceeq,x^i*y^(2-i)],{i,0,2}]/.{x->0,y->0}//Simplify
c2sol = Solve[%=={0,0,0},Table[a[i,2-i],{i,0,2}]][[1]]

After substituting these, we can look for the coefficients of degrees 3, which turn out be all zero.

invarianceeq2=(invarianceeq/.c2sol);
cl3 =  Table[Coefficient[invarianceeq2,x^i*y^(3-i)],{i,0,3}]/.{x->0,y->0}//Simplify;
c3sol = Solve[%=={0,0,0,0},Table[a[i,3-i],{i,0,3}]][[1]]

psi0 = psi/.c2sol/.c3sol//Expand
Plot3D[psi0,{x,0,1},{y,0,1}]

We can use (x,y) as coordinates on the center manifold. The ODE is found by substituting psi for z in the ODE’s for (x, y).  Here it is to third order.

xdotcenter =  xdot/.z->psi0//Expand
ydotcenter =  ydot/.z->psi0

It is still not obvious whether the origin is stable or not.  For this we try to get the planar ODE into rotation invariant form.  But at the center manifold reduction is a preliminary step for this approach.

Here is a numerical solution of the planar ODE on the center manifold which seems to indicate stability.

centereq = {x'[t]==(xdotcenter/.{x->x[t],y->y[t]}),y'[t]==(ydotcenter/.{x->x[t],y->y[t]})}
s={x[t],y[t]}/.NDSolve[centereq~Join~{x[0]==1,y[0]==0},{x[t],y[t]},{t,0,100}][[1]];
ParametricPlot[s,{t,0,100}]

Normal form for a center in the plane

The normal form theory for planar centers uses complex coordinates z =  x+I*y and w = x-I*y.   Here is the equation for zdot and wdot.

zdot =  xdotcenter +I*ydotcenter /.{x->(z+w)/2, y->(z-w)/(2*I)}//Expand
wdot =  xdotcenter -I*ydotcenter  /.{x->(z+w)/2, y->(z-w)/(2*I)}//Expand

It turns out that by a further change of coordinates we can eliminate all terms of zdot except those of the form (zw)^k z.  In the wdot equation we keep only the terms of the form (zw)^k w.  This gives

zdotnormalform =I z-((1/20)+(I/40)) w (z^2)//Factor
wdotnormalform =-I w-((1/20)-(I/40)) (w^2) z//Factor

The square of the radius rsq =  z*w.  It’s derivative is

rsqdot = zdotnormalform*w+z*wdotnormalform/.w->rsq/z//Expand

This shows that rsq is monotonically decreasing and so the origin is asymptotically stable in the center manifold.  Since the other eigenvalue was negative, the origin is also asymptotically stable in R^3.